Subversion Repositories QNX 8.QNX8 LLVM/Clang compiler suite

Rev

Blame | Last modification | View Log | Download | RSS feed

  1. # Check if the host compiler is new enough.
  2. # These versions are updated based on the following policy:
  3. #   llvm.org/docs/DeveloperPolicy.html#toolchain
  4.  
  5. include(CheckCXXSourceCompiles)
  6.  
  7. set(GCC_MIN 7.1)
  8. set(GCC_SOFT_ERROR 7.1)
  9. set(CLANG_MIN 5.0)
  10. set(CLANG_SOFT_ERROR 5.0)
  11. set(APPLECLANG_MIN 10.0)
  12. set(APPLECLANG_SOFT_ERROR 10.0)
  13.  
  14. # https://en.wikipedia.org/wiki/Microsoft_Visual_C#Internal_version_numbering
  15. # _MSC_VER == 1927 MSVC++ 14.27 Visual Studio 2019 Version 16.7
  16. set(MSVC_MIN 19.27)
  17. set(MSVC_SOFT_ERROR 19.27)
  18.  
  19. set(LIBSTDCXX_MIN 7)
  20. set(LIBSTDCXX_SOFT_ERROR 7)
  21.  
  22.  
  23. if(DEFINED LLVM_COMPILER_CHECKED)
  24.   return()
  25. endif()
  26. set(LLVM_COMPILER_CHECKED ON)
  27.  
  28. if(LLVM_FORCE_USE_OLD_TOOLCHAIN)
  29.   return()
  30. endif()
  31.  
  32. function(check_compiler_version NAME NICE_NAME MINIMUM_VERSION SOFT_ERROR_VERSION)
  33.   if(NOT CMAKE_CXX_COMPILER_ID STREQUAL NAME)
  34.     return()
  35.   endif()
  36.   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS MINIMUM_VERSION)
  37.     message(FATAL_ERROR "Host ${NICE_NAME} version must be at least ${MINIMUM_VERSION}, your version is ${CMAKE_CXX_COMPILER_VERSION}.")
  38.   elseif(CMAKE_CXX_COMPILER_VERSION VERSION_LESS SOFT_ERROR_VERSION)
  39.     if(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN)
  40.       message(WARNING "Host ${NICE_NAME} version should be at least ${SOFT_ERROR_VERSION} because LLVM will soon use new C++ features which your toolchain version doesn't support. Your version is ${CMAKE_CXX_COMPILER_VERSION}. Ignoring because you've set LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
  41.     else()
  42.       message(FATAL_ERROR "Host ${NICE_NAME} version should be at least ${SOFT_ERROR_VERSION} because LLVM will soon use new C++ features which your toolchain version doesn't support. Your version is ${CMAKE_CXX_COMPILER_VERSION}. You can temporarily opt out using LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
  43.     endif()
  44.   endif()
  45. endfunction(check_compiler_version)
  46.  
  47. check_compiler_version("GNU" "GCC" ${GCC_MIN} ${GCC_SOFT_ERROR})
  48. check_compiler_version("Clang" "Clang" ${CLANG_MIN} ${CLANG_SOFT_ERROR})
  49. check_compiler_version("AppleClang" "Apple Clang" ${APPLECLANG_MIN} ${APPLECLANG_SOFT_ERROR})
  50. check_compiler_version("MSVC" "Visual Studio" ${MSVC_MIN} ${MSVC_SOFT_ERROR})
  51.  
  52. # See https://developercommunity.visualstudio.com/content/problem/845933/miscompile-boolean-condition-deduced-to-be-always.html
  53. # and thread "[llvm-dev] Longstanding failing tests - clang-tidy, MachO, Polly"
  54. # on llvm-dev Jan 21-23 2020.
  55. if ((${CMAKE_CXX_COMPILER_ID} STREQUAL MSVC) AND
  56.     (19.24 VERSION_LESS_EQUAL ${CMAKE_CXX_COMPILER_VERSION}) AND
  57.     (${CMAKE_CXX_COMPILER_VERSION} VERSION_LESS 19.25))
  58.   if(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN)
  59.     message(WARNING "Host Visual Studio version 16.4 is known to miscompile part of LLVM")
  60.   else()
  61.     message(FATAL_ERROR "Host Visual Studio version 16.4 is known to miscompile part of LLVM, please use clang-cl or upgrade to 16.5 or above (use -DLLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN=ON to ignore)")
  62.   endif()
  63. endif()
  64.  
  65.  
  66. if(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  67.   if (CMAKE_CXX_SIMULATE_ID MATCHES "MSVC")
  68.     if (CMAKE_CXX_SIMULATE_VERSION VERSION_LESS MSVC_MIN)
  69.       message(FATAL_ERROR "Host Clang must have at least -fms-compatibility-version=${MSVC_MIN}, your version is ${CMAKE_CXX_SIMULATE_VERSION}.")
  70.     endif()
  71.     set(CLANG_CL 1)
  72.   elseif(NOT LLVM_ENABLE_LIBCXX)
  73.     # Test that we aren't using too old of a version of libstdc++.
  74.     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  75.     set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  76.     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++0x")
  77.     check_cxx_source_compiles("
  78. #include <iosfwd>
  79. #if defined(__GLIBCXX__)
  80. #if !defined(_GLIBCXX_RELEASE) || _GLIBCXX_RELEASE < ${LIBSTDCXX_MIN}
  81. #error Unsupported libstdc++ version
  82. #endif
  83. #endif
  84. int main() { return 0; }
  85. "
  86.       LLVM_LIBSTDCXX_MIN)
  87.     if(NOT LLVM_LIBSTDCXX_MIN)
  88.       message(FATAL_ERROR "libstdc++ version must be at least ${GCC_MIN}.")
  89.     endif()
  90.     check_cxx_source_compiles("
  91. #include <iosfwd>
  92. #if defined(__GLIBCXX__)
  93. #if !defined(_GLIBCXX_RELEASE) || _GLIBCXX_RELEASE < ${LIBSTDCXX_SOFT_ERROR}
  94. #error Unsupported libstdc++ version
  95. #endif
  96. #endif
  97. int main() { return 0; }
  98. "
  99.       LLVM_LIBSTDCXX_SOFT_ERROR)
  100.     if(NOT LLVM_LIBSTDCXX_SOFT_ERROR)
  101.       if(LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN)
  102.         message(WARNING "libstdc++ version should be at least ${LIBSTDCXX_SOFT_ERROR} because LLVM will soon use new C++ features which your toolchain version doesn't support. Ignoring because you've set LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
  103.       else()
  104.         message(FATAL_ERROR "libstdc++ version should be at least ${LIBSTDCXX_SOFT_ERROR} because LLVM will soon use new C++ features which your toolchain version doesn't support. You can temporarily opt out using LLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN, but very soon your toolchain won't be supported.")
  105.       endif()
  106.     endif()
  107.     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
  108.     set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
  109.   endif()
  110. endif()
  111.